Cheat Engine

[poli123]

how to learn the script example tis ::[ENABLE]
alloc(MyCode,1024)

//=========================================
// Declaration section
label(_MonSelected)
label(_BackMS)
label(_GodMode)
label(_BackGM)
label(_ExitGM)
label(_MonMana)
label(_BackMM)
label(_ExitMM)
label(_MonMana1)
label(_BackMM1)
label(_ExitMM1)
label(_MonBreath)
label(_BackMB)
label(_ExitMB)
label(pSelected)
label(iEnableGM)
label(iEnableMM)
label(iEnableMB)

registersymbol(MyCode)
registersymbol(pSelected)
registersymbol(iEnableGM)
registersymbol(iEnableMM)
registersymbol(iEnableMB)

//=========================================
// Hacking Points
trine.exe+30ad3a:
jmp _MonSelected
nop
_BackMS:

trine.exe+291d4d:
jmp _GodMode
nop
_BackGM:

trine.exe+284c31:
jmp _MonMana
nop
nop
_BackMM:

trine.exe+2832a3:
jmp _MonMana1
nop
nop
_BackMM1:

trine.exe+32b304:
jmp _MonBreath
nop
_BackMB:

MyCode:
//=========================================
_MonSelected:
mov [pSelected],ecx // Save pointer for further use

cmp [edx+trine.exe+46fe58],ecx // Original code
jmp _BackMS // Back to main code

//=========================================
// God Mode
_GodMode:
cmp dword ptr [iEnableGM],0
je _ExitGM // Jump if feature is disabled

cmp ebx,[pSelected] // Player´s unit?
jne _ExitGM // Jump if falae

mov dword ptr [esp+40],0 // Value_to_decrease = 0

mov eax,[ebx+00000258]
mov [ebx+00000254],eax // Current HP = Maximum

_ExitGM:
mov eax,[ebx+00000254] // Original code
jmp _BackGM // Back to main code

//=========================================
_MonMana:
cmp dword ptr [iEnableMM],0
je _ExitMM // Jump if feature is disabled

cmp esi,[pSelected] // Player´s unit?
jne _ExitMM // Jump if falae

cmp eax,1 // Mana?
jne _ExitMM // Jump if false

xor ecx,ecx // Value_to_decrease = 0

_ExitMM:
sub [esi+eax*4+0000078c],ecx // Original code
jmp _BackMM // Back to main code

//=========================================
_MonMana1:
cmp dword ptr [iEnableMM],0
je _ExitMM1 // Jump if feature is disabled

cmp edx,[pSelected] // Player´s unit?
jne _ExitMM1 // Jump if falae

cmp eax,1 // Mana?
jne _ExitMM1 // Jump if false

cmp esi,[edx+eax*4+0000078c] // Greater than current value?
jge _ExitMM1 // Jump if true

mov esi,[edx+eax*4+0000078c] // Get current value

_ExitMM1:
mov [edx+eax*4+0000078c],esi // Original code
cmp esi,ecx // Original code
jmp _BackMM1 // Back to main code

//=========================================
_MonBreath:
pushfd
fstp dword ptr [ecx+00000f5c] // Original code

cmp dword ptr [iEnableMB],0
je _ExitMB // Jump if feature is disabled

cmp ecx,[pSelected] // Player´s unit?
jne _ExitMB // Jump if falae

mov dword ptr [ecx+00000f5c],3f800000 // Breath = 100%

_ExitMB:
popfd
jmp _BackMB // Back to main code

//=========================================
// Variables
pSelected:
dd 0
iEnableGM:
dd 1
iEnableMM:
dd 1
iEnableMB:
dd 1
//=========================================
// Original Codes
[DISABLE]
trine.exe+30ad3a:
cmp [edx+trine.exe+46fe58],ecx

trine.exe+291d4d:
mov eax,[ebx+00000254]

trine.exe+284c31:
sub [esi+eax*4+0000078c],ecx

trine.exe+2832a3:
mov [edx+eax*4+0000078c],esi

trine.exe+32b304:
fstp dword ptr [ecx+00000f5c]

dealloc(MyCode)
unregistersymbol(MyCode)
unregistersymbol(pSelected)
unregistersymbol(iEnableGM)
unregistersymbol(iEnableMM)
unregistersymbol(iEnableMB)

and how to can teach me how to hack restaurant city