Cheat Engine Forum Index Cheat Engine
The Official Site of Cheat Engine
 
 FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   RegisterRegister 
 ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in 


Order Of War (DX9) Version 1.0.1858 (GM and more)

 
Post new topic   Reply to topic    Cheat Engine Forum Index -> Auto Assemble scripts
View previous topic :: View next topic  
Author Message
Recifense
I post too much
Reputation: 123

Joined: 17 Mar 2008
Posts: 2568
Location: Recife - Pernambuco - Brazil

PostPosted: Thu Nov 05, 2009 11:26 am    Post subject: Order Of War (DX9) Version 1.0.1858 (GM and more) Reply with quote

Hi guys,

I am back. And here is my contribution for "Order Of War" Version 1.0.1858. The script contains the following features:

- God Mode;
- Unlimited Resources ;
- Unlimited Points;

It is for CE 5.5

Here is the script:

Code:

//=========================================
// Order Of War (DX9)
// Game Version  : 1.0.1858(.25593)
// Script Version: 1.0
// CE Version    : 5.5
// Resource, GodMode, Points
// 15-Oct-2009
//=========================================

[ENABLE]
alloc(MyCode,1024)

//=========================================
// Declaration section
label(_MonDisp)
label(_MonRes)
label(_BackMR)
label(_ExitMR)
label(_MonHP)
label(_BackMH)
label(_ExitMH)
label(_MonPoints)
label(_BackMP)
label(_ExitMP)
label(_IniVar)
label(_BackIV)
label(iEnableMR)
label(iEnableMH)
label(iEnableMP)
label(pDisp)
label(iPlayerID)

registersymbol(MyCode)
registersymbol(iEnableMR)
registersymbol(iEnableMH)
registersymbol(iEnableMP)

//=========================================
// Hacking Points
oow_final_dx9.exe+2aaafc:
 jmp _MonDisp
 
oow_final_dx9.exe+2af1d4:
 jmp _MonRes
_BackMR:

oow_final_dx9.exe+2ad386:
 jmp _MonHP
_BackMH:

oow_final_dx9.exe+31ba82:
 jmp _MonPoints
 nop
_BackMP:

oow_final_dx9.exe+11ced4:
 jmp _IniVar
 nop
_BackIV:

MyCode:
//=========================================
_MonDisp:
 mov [pDisp],eax             // Save ptr for further use

 fld dword ptr [eax+08]      // Original code
 pop ecx                     // Original code
 ret 0004                    // Original code

//=========================================
_MonRes:
 cmp dword ptr [iEnableMR],0
 je _ExitMR                  // Jump if feature is disabled

 cmp ebx,[pDisp]             // Player´s Resource?
 jne _ExitMR                 // Jump if false

 mov eax,[edx]               // Get player id
 mov [iPlayerID],eax         // Save it for further use
 
 mov eax,43fa0000            // 500 (float)
 cmp eax,[edx+04]            // Current value >= minimum?
 jle _ExitMR                 // Jump if true
 
 mov [edx+04],eax            // Update current value

_ExitMR:
 fstp dword ptr [ebx+08]     // Original code
 mov eax,[esi]               // Original code
 jmp _BackMR                 // Back to main code

//=========================================
_MonHP:
 push ebx
 
 cmp dword ptr [iEnableMH],0
 je _ExitMH                  // Jump if feature is disabled

 mov ebx,[esi+10]            // Get unit owner id
 cmp ebx,[iPlayerID]         // Player´s unit?
 jne _ExitMH                 // Jump if false

 mov ebx,#50000
 cmp ebx,[ecx+10]            // Current value >= minimum?
 jle _ExitMH                 // Jump if true
 
 mov [ecx+10],ebx            // Update current value

_ExitMH:
 pop ebx

 add ebp,[ecx+10]            // Original code
 cmp eax,ebx                 // Original code
 jmp _BackMH                 // Back to main code

//=========================================
_MonPoints:
 mov [esi+00000144],eax      // Original code

 cmp dword ptr [iEnableMP],0
 je _ExitMP                  // Jump if feature is disabled

 mov eax,#5000
 cmp eax,[esi+00000144]      // Current value >= Minimum?
 jle _ExitMP                 // Jump if true
 
 mov [esi+00000144],eax      // Make current value = minimum

_ExitMP:
 jmp _BackMP                 // Back to main code

//=========================================
_IniVar:
 mov [oow_final_dx9.exe+00BB8208],esi // Original code
 
 mov [pDisp],esi             // Initialize to any value
 mov [iPlayerID],esi         // Initialize to any value
 
 jmp _BackIV                 // Back to main code

//=========================================
// Variables
iEnableMR:
 dd 1
iEnableMH:
 dd 1
iEnableMP:
 dd 1
pDisp:
 dd MyCode
iPlayerID:
 dd MyCode

//=========================================
// Original Codes
[DISABLE]
oow_final_dx9.exe+2aaafc:
 fld dword ptr [eax+08]
 pop ecx
 ret 0004
 
oow_final_dx9.exe+2af1d4:
 fstp dword ptr [ebx+08]
 mov eax,[esi]

oow_final_dx9.exe+2ad386:
 add ebp,[ecx+10]
 cmp eax,ebx

oow_final_dx9.exe+31ba82:
 mov [esi+00000144],eax

oow_final_dx9.exe+11ced4:
 mov [oow_final_dx9.exe+00BB8208],esi
 
dealloc(MyCode)
unregistersymbol(MyCode)
unregistersymbol(iEnableMR)
unregistersymbol(iEnableMH)
unregistersymbol(iEnableMP)


Here are some info for adapting it to other versions of this game:

Hacking points:

_MonDisp
Code:

006AAADE - 8d 54 24 08                - lea edx,[esp+08]
006AAAE2 - 52                         - push edx
006AAAE3 - 8b ce                      - mov ecx,esi
006AAAE5 - 89 44 24 14                - mov [esp+14],eax
006AAAE9 - e8 52 d5 ff ff             - call logic::gameclient::oninitinstance+216c20
006AAAEE - 8b 44 24 04                - mov eax,[esp+04]
006AAAF2 - 3b c6                      - cmp eax,esi
006AAAF4 - 5e                         - pop esi
006AAAF5 - 74 0c                      - je logic::gameclient::oninitinstance+2196e3
006AAAF7 - 83 c0 14                   - add eax,14
006AAAFA - 74 07                      - je logic::gameclient::oninitinstance+2196e3
006AAAFC - d9 40 08                   - fld dword ptr [eax+08]      [b]<--- Hacking Point[/b]
006AAAFF - 59                         - pop ecx
006AAB00 - c2 04 00                   - ret 0004
006AAB03 - d9 ee                      - fldz
006AAB05 - 59                         - pop ecx


_MonRes
Code:

006AF1BB - 8d 4b 30                   - lea ecx,[ebx+30]
006AF1BE - 89 44 24 14                - mov [esp+14],eax
006AF1C2 - e8 e9 fa ff ff             - call logic::gameclient::oninitinstance+21d890
006AF1C7 - 8b 4f 14                   - mov ecx,[edi+14]
006AF1CA - 8b d8                      - mov ebx,eax
006AF1CC - 8b 06                      - mov eax,[esi]
006AF1CE - 50                         - push eax
006AF1CF - e8 9c 94 f3 ff             - call logic::gameclient::oninitinstance+157250
006AF1D4 - d9 5b 08                   - fstp dword ptr [ebx+08]     [b]<--- Hacking Point[/b]
006AF1D7 - 8b 06                      - mov eax,[esi]
006AF1D9 - 8b 4f 14                   - mov ecx,[edi+14]
006AF1DC - 50                         - push eax
006AF1DD - e8 be 94 f3 ff             - call logic::gameclient::oninitinstance+157280
006AF1E2 - d9 5b 04                   - fstp dword ptr [ebx+04]
006AF1E5 - 8b ce                      - mov ecx,esi
006AF1E7 - e8 04 56 e5 ff             - call logic::gameclient::oninitinstance+733d0


_MonHP
Code:

006AD372 - 84 d2                      - test dl,dl
006AD374 - 74 0c                      - je logic::gameclient::oninitinstance+21bf62
006AD376 - 8b 54 24 54                - mov edx,[esp+54]
006AD37A - 8b 52 38                   - mov edx,[edx+38]
006AD37D - 8b 0c 8a                   - mov ecx,[edx+ecx*4]
006AD380 - eb 02                      - jmp logic::gameclient::oninitinstance+21bf64
006AD382 - 33 c9                      - xor ecx,ecx
006AD384 - 8b 00                      - mov eax,[eax]
006AD386 - 03 69 10                   - add ebp,[ecx+10]   <--- Hacking Point
006AD389 - 39 d8                      - cmp eax,ebx
006AD38B - 75 ca                      - jne logic::gameclient::oninitinstance+21bf37
006AD38D - 89 6c 24 10                - mov [esp+10],ebp
006AD391 - d9 46 20                   - fld dword ptr [esi+20]
006AD394 - db 44 24 10                - fild dword ptr [esp+10]
006AD398 - da 74 24 14                - fidiv [esp+14]
006AD39C - d9 ee                      - fldz


_MonPoints
Code:

0071BA6E - 6a 00                      - push 00
0071BA70 - 68 c0 60 f9 00             - push 00f960c0
0071BA75 - 68 10 33 f8 00             - push 00f83310
0071BA7A - 8b f1                      - mov esi,ecx
0071BA7C - 8b 16                      - mov edx,[esi]
0071BA7E - 6a 00                      - push 00
0071BA80 - 6a 00                      - push 00
0071BA82 - 89 86 44 01 00 00          - mov [esi+00000144],eax    <--- Hacking Point
0071BA88 - 8b 42 18                   - mov eax,[edx+18]
0071BA8B - 68 94 93 dd 00             - push 00dd9394
0071BA90 - ff d0                      - call eax
0071BA92 - 50                         - push eax
0071BA93 - e8 be 25 59 00             - call 00cae056
0071BA98 - 8b 16                      - mov edx,[esi]
0071BA9A - 83 c4 14                   - add esp,14
0071BA9D - 6a 00                      - push 00


_IniVar
Code:

0051CEA7 - c6 44 24 2c 12             - mov byte ptr [esp+2c],12
0051CEAC - 89 9e e0 00 00 00          - mov [esi+000000e0],ebx
0051CEB2 - c7 86 e4 00 00 00 e8 03 00 00 - mov [esi+000000e4],000003e8
0051CEBC - 89 9e e8 00 00 00          - mov [esi+000000e8],ebx
0051CEC2 - e8 09 7f ff ff             - call logic::gameclient::oninitinstance+839b0
0051CEC7 - 89 9e 10 01 00 00          - mov [esi+00000110],ebx
0051CECD - 6a 48                      - push 48
0051CECF - c6 44 24 20 13             - mov byte ptr [esp+20],13
0051CED4 - 89 35 08 82 fb 00          - mov [00fb8208],esi <--- Hacking Point
0051CEDA - e8 61 48 55 00             - call 00a71740
0051CEDF - 83 c4 04                   - add esp,04
0051CEE2 - 89 44 24 10                - mov [esp+10],eax
0051CEE6 - 3b c3                      - cmp eax,ebx
0051CEE8 - c6 44 24 1c 14             - mov byte ptr [esp+1c],14
0051CEED - 74 09                      - je logic::gameclient::oninitinstance+8bad8
0051CEEF - 8b c8                      - mov ecx,eax


My notes:
Code:

Order of War:

struct Resource:
0000 = iIndex
0004 = fResource
0008 = fIncConstant(?)

struct HP:
0000 = 00dc9f98
0008 = iIndex
000c = iTroopID (1000, 1001, etc)
0010 = icHP
0014 = i3

Struct Points:
0000 = 00dda784
0004 = 00dda868
0144 = iPoints


That´s it.

Cheers.



OrderOfWar_GM_More.CEA
 Description:

Download
 Filename:  OrderOfWar_GM_More.CEA
 Filesize:  4.06 KB
 Downloaded:  2770 Time(s)

Back to top
View user's profile Send private message Send e-mail
BeetleJuice
How do I cheat?
Reputation: 0

Joined: 03 Oct 2008
Posts: 4
Location: Missouri

PostPosted: Mon Aug 23, 2010 8:31 pm    Post subject: Order of War DX10 Reply with quote

You wouldn't happen to have an updated version for this game would you?

I'm stuck with this Order of War (DX10)..
Back to top
View user's profile Send private message
Display posts from previous:   
Post new topic   Reply to topic    Cheat Engine Forum Index -> Auto Assemble scripts All times are GMT - 6 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum



Powered by phpBB © 2001, 2005 phpBB Group

CE Wiki   IRC (#CEF)