Cheat Engine Forum Index Cheat Engine
The Official Site of Cheat Engine
 
 FAQFAQ   SearchSearch   MemberlistMemberlist   UsergroupsUsergroups   RegisterRegister 
 ProfileProfile   Log in to check your private messagesLog in to check your private messages   Log inLog in 


Darksiders V1.1 (GM and More)

 
Post new topic   Reply to topic    Cheat Engine Forum Index -> Auto Assemble scripts
View previous topic :: View next topic  
Author Message
Recifense
I post too much
Reputation: 121

Joined: 17 Mar 2008
Posts: 2527
Location: Recife - Pernambuco - Brazil

PostPosted: Thu Oct 14, 2010 6:47 pm    Post subject: Darksiders V1.1 (GM and More) This post has 1 review(s) Reply with quote

Hi guys,

Here is my contribution for "Darksiders" Version 1.1. The script contains the following features:

- God Mode;
- Unlimited Wrath Power;
- Unlimited Blue Souls; (The total collected souls is recovered after buying something)
- Unlimited Chaos Power;

It is for CE 5.6

Note: The script now uses the new CE command assert and will not load if it is incompatible with the running game version.

Here is the script:

Code:

{
===========================================
 Darksiders
 Game Version  : 1.1
 Script Version: 1.0
 CE Version    : 5.6
 GodMode, Wrath, Currency, Chaos
 12-Oct-2010
===========================================
}

[ENABLE]
//=========================================
// Check if script is compatible to this game version
// If false the script will not be loaded

assert(DarksidersPC.exe+413e1d,f3 0f 10 8b 00 01 00 00)
assert(DarksidersPC.exe+29fdc6,f3 0f 11 46 04)
assert(DarksidersPC.exe+153ece,f3 0f 10 80 54 06 00 00)
assert(DarksidersPC.exe+0f2741,8b 81 3c 06 00 00)
assert(DarksidersPC.exe+417715,8b 40 14 89 41 48)

//=========================================
alloc(MyCode,1024)
//=========================================
// Declaration section
label(_GodMode)
label(_BackGM)
label(_ExitGM)
label(_MonWrathPower)
label(_BackMWP)
label(_ExitMWP)
label(_MonBlueSouls)
label(_BackMBS)
label(_ExitMBS)
label(_MonChaosPower)
label(_BackMCP)
label(_ExitMCP)
label(_MonChaosPower1)
label(_BackMCP1)
label(_ExitMCP1)
label(pHero)
label(pWeapon)
label(iEnableGM)
label(iEnableMWP)
label(iEnableMBS)
label(iEnableMCP)
label(iTest)

registersymbol(MyCode)
registersymbol(pHero)
registersymbol(pWeapon)
registersymbol(iEnableGM)
registersymbol(iEnableMWP)
registersymbol(iEnableMBS)
registersymbol(iEnableMCP)

//=========================================
MyCode:
//=========================================
_GodMode:
 mov [pHero],ebx                // Save pointer for debugging

 cmp dword ptr [iEnableGM],0
 je _ExitGM                     // Jump if feature is disabled

 cvtsi2ss xmm1,[ebx+000001dc]   // Get max HP
 movss [ebx+00000100],xmm1      // Make Current HP = maximum
 
 xorps xmm0,xmm0                // Make xmm0 = 0
 movss [edi+20],xmm0            // value2decrease = 0

_ExitGM:
 movss xmm1,[ebx+00000100]      // Original code
 jmp _BackGM                    // Back to main code

//=========================================
_MonWrathPower:
 cmp dword ptr [iEnableMWP],0
 je _ExitMWP                    // Jump if feature is disabled

 mov eax,[esi+24]               // Get # slots wraith power
 or eax,eax
 jz _ExitMWP                    // Jump if none available
 
 mov [esi],eax                  // Update # full slots
 imul eax,[esi+28]              // multiply it by "base value of wraith power"

 mov [iTest],eax                // Save it for changing
 cvtsi2ss xmm0,[iTest]          // Change result to single float

_ExitMWP:
 movss [esi+04],xmm0            // Original code (update wraith power)
 jmp _BackMWP                   // Back to main code

//=========================================
// Currency
_MonBlueSouls:
 cmp dword ptr [iEnableMBS],0
 je _ExitMBS                    // Jump if feature is disabled

 mov edx,[eax+0000053c]         // Get pointer to Statistic Structure
 or edx,edx
 jz _ExitMBS
 
 cvtsi2ss xmm0,[edx+70]         // Get total souls colected and convert it to float
 
 movss [eax+00000654],xmm0      // Update available blue souls (currency)
 
_ExitMBS:
 movss xmm0,[eax+00000654]      // Original code (update wraith power)
 jmp _BackMBS                   // Back to main code

//=========================================
_MonChaosPower:
 push ebx
 push edx
 
 mov eax,[ecx+0000063c]         // Original code
 test eax,eax
 jz _ExitMCP                    // Jump if null pointer
 
 cmp dword ptr [iEnableMCP],0
 je _ExitMCP                    // Jump if feature is disabled

 mov edx,[ecx+0000064c]         // Get ptr to powers
 test edx,edx
 jz _ExitMCP                    // Jump if null pointer
 
 mov ebx,[eax+48]               // Get maximum # Chaos
 or ebx,ebx
 jz _ExitMCP
 
 mov [edx+14],ebx               // Uppdate current # Chaos
 mov ebx,[eax+44]               // Get maximum Chaos Power
 mov [edx+08],ebx               // Uppdate current Chaos Power
 mov ebx,#9999999               
 mov [ecx+00000208],ebx         // Extend time of Chaos
 
_ExitMCP:
 pop edx
 pop ebx
 jmp _BackMCP                   // Back to main code

//=========================================
_MonChaosPower1:
 mov eax,[eax+14]               // Original code
 
 cmp dword ptr [iEnableMCP],0
 je _ExitMCP1                   // Jump if feature is disabled

 cmp eax,[ecx+48]
 jge _ExitMCP1
 
 mov eax,[ecx+48]               // Get current # chaos
 
_ExitMCP1:
 mov [ecx+48],eax               // Original code
 jmp _BackMCP1                  // Back to main code

//=========================================
// Variables
pHero:
 dd 0
pWeapon:
 dd 0
iEnableGM:
 dd 1
iEnableMWP:
 dd 1
iEnableMBS:
 dd 1
iEnableMCP:
 dd 1
iTest:
 dd 0

//=========================================
// Hacking Points
DarksidersPC.exe+413e1d:
 jmp _GodMode
 nop
 nop
 nop
_BackGM:

DarksidersPC.exe+29fdc6:
 jmp _MonWrathPower
_BackMWP:

DarksidersPC.exe+153ece:
 jmp _MonBlueSouls
 nop
 nop
 nop
_BackMBS:
 
DarksidersPC.exe+0f2741:
 jmp _MonChaosPower
 nop
_BackMCP:

DarksidersPC.exe+417715:
 jmp _MonChaosPower1
 nop
_BackMCP1:

//=========================================
// Original Codes
[DISABLE]
DarksidersPC.exe+413e1d:
 movss xmm1,[ebx+00000100]

DarksidersPC.exe+29fdc6:
 movss [esi+04],xmm0

DarksidersPC.exe+153ece:
 movss xmm0,[eax+00000654]

DarksidersPC.exe+0f2741:
 mov eax,[ecx+0000063c]

DarksidersPC.exe+417715:
 mov eax,[eax+14]
 mov [ecx+48],eax

unregistersymbol(MyCode)
unregistersymbol(pHero)
unregistersymbol(pWeapon)
unregistersymbol(iEnableGM)
unregistersymbol(iEnableMWP)
unregistersymbol(iEnableMBS)
unregistersymbol(iEnableMCP)

dealloc(MyCode)


Here are some information for adapting the script for other game versions:

Code:

_GodMode:  (DarksidersPC.exe+413e1d)

00813DDD - f3 0f 2a c8                - cvtsi2ss xmm1,xmm0
00813DE1 - f3 0f 59 c8                - mulss xmm1,xmm0
00813DE5 - f3 0f 59 0d c4 e9 cb 00    - mulss xmm1,[00cbe9c4] : [(float)0.0100]
00813DED - f3 0f 11 4f 20             - movss [edi+20],xmm1
00813DF2 - f3 0f 10 4f 20             - movss xmm1,[edi+20]
00813DF7 - f3 0f 10 83 00 01 00 00    - movss xmm0,[ebx+00000100]
00813DFF - 0f 2f c1                   - comiss xmm0,xmm1
00813E02 - 8b 83 3c 05 00 00          - mov eax,[ebx+0000053c]
00813E08 - 76 29                      - jna 00813e33
00813E0A - f3 0f 10 40 38             - movss xmm0,[eax+38]
00813E0F - f3 0f 58 c1                - addss xmm0,xmm1
00813E13 - f3 0f 11 40 38             - movss [eax+38],xmm0
00813E18 - f3 0f 10 47 20             - movss xmm0,[edi+20]
00813E1D - f3 0f 10 8b 00 01 00 00    - movss xmm1,[ebx+00000100] <--- HP
00813E25 - f3 0f 5c c8                - subss xmm1,xmm0
00813E29 - f3 0f 11 8b 00 01 00 00    - movss [ebx+00000100],xmm1
00813E31 - eb 15                      - jmp 00813e48
00813E33 - f3 0f 58 40 38             - addss xmm0,[eax+38]
00813E38 - f3 0f 11 40 38             - movss [eax+38],xmm0
00813E3D - 0f 57 c0                   - xorps xmm0,xmm0
00813E40 - f3 0f 11 83 00 01 00 00    - movss [ebx+00000100],xmm0
00813E48 - f3 0f 10 83 00 01 00 00    - movss xmm0,[ebx+00000100]
00813E50 - 0f 2e 05 20 95 cb 00       - ucomiss xmm0,[00cb9520] : [00000000]
00813E57 - 9f                         - lahf
00813E58 - f6 c4 44                   - test ah,44
00813E5B - 0f 8a ed 00 00 00          - jp 00813f4e
00813E61 - 80 7f 1a 07                - cmp byte ptr [edi+1a],07
00813E65 - 0f 84 e3 00 00 00          - je 00813f4e
00813E6B - f6 05 00 33 64 01 01       - test byte ptr [01643300],01
00813E72 - 75 28                      - jne 00813e9c
00813E74 - 83 0d 00 33 64 01 01       - or dword ptr [01643300],01
00813E7B - 83 64 24 34 00             - and dword ptr [esp+34],00
00813E80 - 6a 00                      - push 00


Code:

_MonBlueSouls:       (DarksidersPC.exe+153ece)

00553EA9 - 8b 07                      - mov eax,[edi]
00553EAB - 8d 4c 24 14                - lea ecx,[esp+14]
00553EAF - 51                         - push ecx
00553EB0 - 8b cf                      - mov ecx,edi
00553EB2 - ff 90 34 01 00 00          - call dword ptr [eax+00000134]
00553EB8 - 8b 4c 24 14                - mov ecx,[esp+14]
00553EBC - 3b cb                      - cmp ecx,ebx
00553EBE - 8b 30                      - mov esi,[eax]
00553EC0 - 74 08                      - je gmatrix2d::gety+53161
00553EC2 - 8b 41 08                   - mov eax,[ecx+08]
00553EC5 - 33 d2                      - xor edx,edx
00553EC7 - ff 50 04                   - call dword ptr [eax+04]
00553ECA - 8b 44 24 10                - mov eax,[esp+10]
00553ECE - f3 0f 10 80 54 06 00 00    - movss xmm0,[eax+00000654]  <--- HP
00553ED6 - 33 d2                      - xor edx,edx
00553ED8 - f3 0f 2c c0                - cvttss2si eax,xmm0
00553EDC - 89 87 44 01 00 00          - mov [edi+00000144],eax
00553EE2 - 88 9f 48 01 00 00          - mov [edi+00000148],bl
00553EE8 - 8d 4c 24 18                - lea ecx,[esp+18]
00553EEC - 42                         - inc edx
00553EED - 89 19                      - mov [ecx],ebx
00553EEF - 83 c1 10                   - add ecx,10
00553EF2 - 4a                         - dec edx
00553EF3 - 79 f8                      - jns gmatrix2d::gety+53184
00553EF5 - 6a 02                      - push 02
00553EF7 - f2 0f 2a c0                - cvtsi2sd xmm0,xmm0
00553EFB - 58                         - pop eax
00553EFC - 50                         - push eax


Code:

_MonChaosPower:   (DarksidersPC.exe+0f2741)

004F2731 - 8b 4d f4                   - mov ecx,[ebp-0c]
004F2734 - 5f                         - pop edi
004F2735 - 5e                         - pop esi
004F2736 - 64 89 0d 00 00 00 00       - mov fs:[00000000],ecx
004F273D - c9                         - leave
004F273E - c2 04 00                   - ret 0004
004F2741 - 8b 81 3c 06 00 00          - mov eax,[ecx+0000063c]   <--- HP
004F2747 - 85 c0                      - test eax,eax
004F2749 - 56                         - push esi
004F274A - 8b 74 24 08                - mov esi,[esp+08]
004F274E - 89 06                      - mov [esi],eax
004F2750 - 74 0a                      - je gacquireinterface::canacquire+28ee9
004F2752 - 83 c0 04                   - add eax,04
004F2755 - 50                         - push eax
004F2756 - ff 15 54 60 c9 00          - call dword ptr [gmatrix2d::getx+3ed049]
004F275C - 8b c6                      - mov eax,esi
004F275E - 5e                         - pop esi
004F275F - c2 04 00                   - ret 0004
004F2762 - 8d 41 08                   - lea eax,[ecx+08]
004F2765 - c3                         - ret
004F2766 - b8 dd fb c2 00             - mov eax,gmatrix2d::getx+386bd2
004F276B - e8 08 38 70 00             - call gmatrix2d::getx+34cf6d
004F2770 - 6a 04                      - push 04
004F2772 - 68 d4 01 00 00             - push 000001d4
004F2777 - e8 c8 db 48 00             - call gmatrix2d::getx+d7339
004F277C - 59                         - pop ecx


Code:

_MonChaosPower1:  (DarksidersPC.exe+417715)

008176F7 - 8b 87 4c 06 00 00          - mov eax,[edi+0000064c]
008176FD - d9 40 08                   - fld dword ptr [eax+08]
00817700 - 8b 8f 3c 06 00 00          - mov ecx,[edi+0000063c]
00817706 - d9 59 44                   - fstp dword ptr [ecx+44]
00817709 - 8b 87 4c 06 00 00          - mov eax,[edi+0000064c]
0081770F - 8b 8f 3c 06 00 00          - mov ecx,[edi+0000063c]
00817715 - 8b 40 14                   - mov eax,[eax+14]  <--- HP
00817718 - 89 41 48                   - mov [ecx+48],eax
0081771B - 8b 07                      - mov eax,[edi]
0081771D - 6a 1f                      - push 1f
0081771F - 8b cf                      - mov ecx,edi
00817721 - ff 90 90 01 00 00          - call dword ptr [eax+00000190]
00817727 - f3 0f 2a 08                - cvtsi2ss xmm1,[eax]
0081772B - 8b 87 4c 06 00 00          - mov eax,[edi+0000064c]
00817731 - f3 0f 10 40 04             - movss xmm0,[eax+04]
00817736 - f3 0f 58 45 d8             - addss xmm0,[ebp-28]
0081773B - 0f 2f c1                   - comiss xmm0,xmm1
0081773E - 76 03                      - jna gmatrix2d::gety+3169da
00817740 - 0f 28 c1                   - movaps xmm0,xmm1
00817743 - 8b 87 3c 06 00 00          - mov eax,[edi+0000063c]
00817749 - f3 0f 11 40 40             - movss [eax+40],xmm0


Code:

_MonWrathPower:  (DarksidersPC.exe+29fdc6)

0069FDB5 - 32 c0                      - xor al,al
0069FDB7 - c2 04 00                   - ret 0004
0069FDBA - 55                         - push ebp
0069FDBB - 8b ec                      - mov ebp,esp
0069FDBD - 51                         - push ecx
0069FDBE - f3 0f 58 46 04             - addss xmm0,[esi+04]
0069FDC3 - 8b 4e 0c                   - mov ecx,[esi+0c]
0069FDC6 - f3 0f 11 46 04             - movss [esi+04],xmm0    <--- HP
0069FDCB - 8b 01                      - mov eax,[ecx]
0069FDCD - 6a 1f                      - push 1f
0069FDCF - ff 90 90 01 00 00          - call dword ptr [eax+00000190]
0069FDD5 - f3 0f 2a 00                - cvtsi2ss xmm0,[eax]
0069FDD9 - 8b 4e 0c                   - mov ecx,[esi+0c]
0069FDDC - 8b 01                      - mov eax,[ecx]
0069FDDE - 6a 20                      - push 20
0069FDE0 - f3 0f 11 45 fc             - movss [ebp-04],xmm0
0069FDE5 - ff 90 90 01 00 00          - call dword ptr [eax+00000190]
0069FDEB - 8b 00                      - mov eax,[eax]
0069FDED - 0f 57 c9                   - xorps xmm1,xmm1
0069FDF0 - f3 0f 10 55 fc             - movss xmm2,[ebp-04]
0069FDF5 - 0f 2f d1                   - comiss xmm2,xmm1
0069FDF8 - 89 46 24                   - mov [esi+24],eax
0069FDFB - 76 18                      - jna 0069fe15
0069FDFD - 83 7e 28 00                - cmp dword ptr [esi+28],00
0069FE01 - 7d 12                      - jnl 0069fe15
0069FE03 - f3 0f 2a c0                - cvtsi2ss xmm0,xmm0
0069FE07 - 0f 28 da                   - movaps xmm3,xmm2
0069FE0A - f3 0f 5e d8                - divss xmm3,xmm0
0069FE0E - f3 0f 2c c3                - cvttss2si eax,xmm3
0069FE12 - 89 46 28                   - mov [esi+28],eax
0069FE15 - 8b 46 24                   - mov eax,[esi+24]
0069FE18 - 85 c0                      - test eax,eax


Code:

My Notes for Darksiders:

DarksidersPC.exe+0122e594 => Static Pointer to Hero

struct hero:
0000 = 00d69d14
0100 = fcHP
01dc = imHP
01e4 = im#Cores (Wrath)
0208 = iExtendChaosTime
053c = pStatistic
063c = pSomeInfo
064c = pPower
0654 = fCurrencySouls  (blue)

struct Powers):
0000 = ic#WrathCores (fWrathPower/50)
0004 = fcWrathPower  (ic#WrathCores*fWrathBase)
0008 = fcChaosPower
000c = pHero
0014 = ic#Chaos
0024 = im#WrathCores
0028 = iWrathBase (=50)

struct Statistic:
0000 = 00d7b56c
0004 = i2
0008 = iKills
000c = i0
0010 = i0
0014 = i0
0018 = iKills
0034 = fSpilledBlood (or Damage inflicted)
0038 = fLostBlood    (or Damage suffered)
004c = fMiles (*56671)
005c = fMiles (*56671)
0070 = iTotalSoulsCollected (blue)
0074 = iTimeInGame (in seconds)
0078 = fTimeInCombat (in seconds)
0080 = iHighestCombo

struct SomeInfo:
0000 = 00d1311c
0038 = fCollectedSouls
003c = imHP
0040 = fmWrath
0044 = fmChaos
0048 = imChaos


Here is also a table that uses the script.

Cheers!



Darksiders_GM_More.CEA
 Description:
The Script

Download
 Filename:  Darksiders_GM_More.CEA
 Filesize:  5.6 KB
 Downloaded:  3428 Time(s)


DarksidersPC.CT
 Description:
The Table

Download
 Filename:  DarksidersPC.CT
 Filesize:  6.19 KB
 Downloaded:  5671 Time(s)

Back to top
View user's profile Send private message Send e-mail
Display posts from previous:   
Post new topic   Reply to topic    Cheat Engine Forum Index -> Auto Assemble scripts All times are GMT - 6 Hours
Page 1 of 1

 
Jump to:  
You cannot post new topics in this forum
You cannot reply to topics in this forum
You cannot edit your posts in this forum
You cannot delete your posts in this forum
You cannot vote in polls in this forum
You cannot attach files in this forum
You can download files in this forum



Powered by phpBB © 2001, 2005 phpBB Group

CE Wiki   IRC (#CEF)